How to use the DHT22 and Arduino to Measure Humidity, Temperature, Dew Point and Heat Index.

The basic function of the DHT22 (or DHT11) is to measure Humidity but in order to do that accurately it also measures temperature (the temperature value compensates the humidity value automatically). You can also obtain the temperature value from the DHT22 - a two for one bonus!

• Humidity,
• Temperature,
• Dew Point (derived from above),
• Heat Index (derived from above).

Code here calculates the dew point; The temperature below which water saturated air releases water as water vapour.

The code also calculates the heat index - an indication of what the temperature "feels-like" due to humidity e.g. the temperature could be 30°C but the humidity makes it "feel-like" 40°C.

This page shows you an Arduino tutorial for the DHT22 which is also applicable to the DHT11 since they use the same electronic interface - the only differences between the devices are in the device specifications i.e. capability and accuracy (DHT22 is the better one because it is newer). However either will measure relative humidity to a good accuracy.

Dew Point and Heat Index are values that can be easily calculated using the Arduino Uno R3 Board with both calculations requiring use of floating point code. Floating point routines take up a lot more memory but are convenient and an alternative is to use fixed point maths but this takes more effort.

These sensors are relative humidity sensors with a built in temperature sensor (which allows the humidity reading to be more accurate - see table below for accuracy of the device). Further on you can learn about details of relative humidity, heat index and dew point. The example, shown further down, shows you how to use the DHT22 in your own Arduino sketches.

DTH22 Pull Up Resistor

The sensor requires a pull up resistor that is specified in the datasheet (1k to 5k is recommended).

The DHT22/11 sensors use a serial communication interface, operating over long distances (over 20m is claimed DHT11, 100m for DHT22). You can buy sensors without a breakout board but the board is convenient and has a 10k pull-up resistor that is on-board. In fact the pull up resistor should be from 5k to 1k then the distance can be further. A stronger (lower) resistance will allow more current and therefore a longer distance.

DHT11 and DHT22 Max cable length:

• DHT11: over 20m
• DHT22: up to 100m

Major differences are:

• DHT22 more expensive than DHT11 (but more accurate).
• DHT22 usable below 0°C.
• DHT22 senses from 0 to 100%RH while DHT11 senses from 20 to 90%RH.

Humidity Accuracy

To measure humidity accurately you have to know the temperature as, to a large extent, the humidity of a gas is dependent on temperature. Both of these sensors measure temperature and as a bonus you can retrieve the temperature value. However note that it is not that accurate for the DHT11; It is quite good for the DHT22. See the device specifications for details.

Relative Humidity

The sensor measures Relative Humidity and this is sometimes misleading concerning the actual water content in the air (which changes with temperature). Working out the dew point can be a better measure since it produces an absolute number (the dew point temperature). This allows you to assess the comfort level of the air i.e. sticky, dry etc. whereas RH may not indicate this (see videos below to understand this difference).

DHT22 vs DHT11 (difference) Specifications:

The data sheet indicates it can cope with a cable length of more than 20m. For less than 20m a 5k pull-up is recommended (most breakout boards have this pull up resistor built-in). If you use more than a 20m cable run then the resistor is not defined and you have to find it experimentally - for a longer cable, resistance increases, therefore you need more current to pull up the voltage successfully, so you you will need a smaller pull-up resistor .

Note : The AM2302 is similar to the RHT03 but has a lower max.cable length and lower max. supply (5.5V). Check the device you have AM2302 is made by Aosong.

DHT22 Datasheet

The DHT22 is also known as the RHT03  - the following datasheet references RHT03.

Download RHT03 Datasheet

Note: The DHT11 is also known as the RHT01.

What is Relative Humidity and the Dew point?

Relative Humidity

You can think of relative humidity as "how close the air is to saturation". It is the amount of moisture in the air compared to the amount that the air can hold at that temperature. Video 2 (below) shows how RH is totally misleading.

Dew Point

If you want to know what the air "feels like" then this is the parameter to calculate!

It is the temperature at which the air is saturated with water. Below the dew point water will saturate out onto solid objects since the air can not hold onto the water when the temperature falls i.e. clouds form, rain or snow falls.

Since the dew point is an absolute number it is often used to define "how the air feels"

Dewpoint tables

[sources http://www.livescience.imwcom/43269-what-is-dew-point.html, http://www.theweatherprediction.com/habyhints/190/, video 2]

Videos and Some Notes on them

1. Vince Condella : Humidity vs Dew point.

https://www.youtube.com/watch?v=S8W-xl4mcJ8

What is the difference between RH and the Dew point? with easy to understand props.

2. NWS Chicago Humidity vs Dew point.

This video shows visually (and with some numbers) what the difference is and shows why an RH of 100% at 55°F feels better than an RH of 50% at 95°F.

3. Mike Hermann Humidity: Relative and absolute.

The water content of air changes with temperature and hotter air can contain more water than colder air.

Absolute humidity : e.g. 5g/m³

Relative humidity : More commonly used in weather reports - it compares amount of vapor to the maximum it can hold (the dew point). Relative humidity changes with temperature.

Heat Index

Humidity Sensor Hardware and software

Arduino Software Setup:

Arduino DHT Library

//#define DHTTYPE DHT11 // DHT 11
#define DHTTYPE DHT22 // DHT 22 (AM2302)
//#define DHTTYPE DHT21 // DHT 21 (AM2301)

Comment out unused sensors leaving your own uncommented.

Library Installation

Github original source is here: dht library on github where you can download and install the library manually.

The above github link is there in case Arduino library manager is changed to not show that library.

An easier way is install it from within the Arduino IDE

1. Goto Menu Sketch --> Include Library --> Manage Libraries...
2. In the Filter Search type DHT.
3. Click on the DHT Sensor Library.
4. Hit install.

Parts for DHT11 project:

1. Processor Board : Arduino Uno R3.
2. DHT11 (either on a breakout board or standalone).
3. 4k7.
4. Breadboard.
5. 10uF Electrolytic.

Note the DHT11 used above, operates identically to the DHT22 it just has a different specification. See table here.

Wiring Layout (Applies to the DHT22 and the DHT11)

Sensor connections

Looking from the front of the device pin one is to the left. These are the connections:

Arduino Sketch

• Without Dew Point function and display : code size = 7688 Bytes
• With Dew Point function and display : code size =6274 Bytes

Create a new sketch, then copy and paste the code below to your own sketch and upload.

Note: Clicking any text in the box below will copy it to the clipboard.

Copy Sketch

// John Main added dewpoint code from : http://playground.arduino.cc/main/DHT11Lib
// Also added DegC output for Heat Index.
// dewPoint function NOAA
// reference (1) : http://wahiduddin.net/calc/density_algorithms.htm
// reference (2) : http://www.colorado.edu/geography/weather_station/Geog_site/about.htm
//
double dewPoint(double celsius, double humidity)
{
  // (1) Saturation Vapor Pressure = ESGG(T)
  double RATIO = 373.15 / (273.15 + celsius);
  double RHS = -7.90298 * (RATIO - 1);
  RHS += 5.02808 * log10(RATIO);
  RHS += -1.3816e-7 * (pow(10, (11.344 * (1 - 1 / RATIO ))) - 1) ;
  RHS += 8.1328e-3 * (pow(10, (-3.49149 * (RATIO - 1))) - 1) ;
  RHS += log10(1013.246);

  // factor -3 is to adjust units - Vapor Pressure SVP * humidity
  double VP = pow(10, RHS - 3) * humidity;

  // (2) DEWPOINT = F(Vapor Pressure)
  double T = log(VP / 0.61078); // temp var
  return (241.88 * T) / (17.558 - T);
}

// Example testing sketch for various DHT humidity/temperature sensors
// Written by ladyada, public domain

#include "DHT.h"

#define DHTPIN 2 // what pin we're connected to

// Uncomment whatever type you're using!
#define DHTTYPE DHT11 // DHT 11
//#define DHTTYPE DHT22 // DHT 22 (AM2302)
//#define DHTTYPE DHT21 // DHT 21 (AM2301)

// Connect pin 1 (on the left) of the sensor to +5V
// NOTE: If using a board with 3.3V logic like an Arduino Due connect pin 1
// to 3.3V instead of 5V!
// Connect pin 2 of the sensor to whatever your DHTPIN is
// Connect pin 4 (on the right) of the sensor to GROUND
// Connect a 10K resistor from pin 2 (data) to pin 1 (power) of the sensor

// Initialize DHT sensor for normal 16mhz Arduino
DHT dht(DHTPIN, DHTTYPE);
// NOTE: For working with a faster chip, like an Arduino Due or Teensy, you
// might need to increase the threshold for cycle counts considered a 1 or 0.
// You can do this by passing a 3rd parameter for this threshold. It's a bit
// of fiddling to find the right value, but in general the faster the CPU the
// higher the value. The default for a 16mhz AVR is a value of 6. For an
// Arduino Due that runs at 84mhz a value of 30 works.
// Example to initialize DHT sensor for Arduino Due:
//DHT dht(DHTPIN, DHTTYPE, 30);

void setup() {
  Serial.begin(9600);
  Serial.println("DHTxx test!");

  dht.begin();
}

void loop() {
  // Wait a few seconds between measurements.
  delay(2000);

  // Reading temperature or humidity takes about 250 milliseconds!
  // Sensor readings may also be up to 2 seconds 'old' (its a very slow sensor)
  float h = dht.readHumidity();
  // Read temperature as Celsius
  float t = dht.readTemperature();
  // Read temperature as Fahrenheit
  float f = dht.readTemperature(true);

  // Check if any reads failed and exit early (to try again).
  if (isnan(h) || isnan(t) || isnan(f)) {
    Serial.println("Failed to read from DHT sensor!");
    return;
  }

  // Compute heat index
  // Must send in temp in Fahrenheit!
  float hi = dht.computeHeatIndex(f, h);
  float hiDegC = dht.convertFtoC(hi);

  Serial.print("Humidity: ");
  Serial.print(h);
  Serial.print(" %\t");
  Serial.print("Temperature: ");
  Serial.print(t);
  Serial.print(" *C ");
  Serial.print(f);
  Serial.print(" *F\t");
  Serial.print("Heat index: ");
  Serial.print(hiDegC);
  Serial.print(" *C ");
  Serial.print(hi);
  Serial.print(" *F ");
  Serial.print("Dew Point (*C): ");
  Serial.println(dewPoint(t, h));
}

Read Function:

This question is asked a lot : What is the function for reading humidity from dht sensor from arduino?

Create an instance of the class:

DHT dht(DHTPIN, DHTTYPE);

Then initialise the library (in the Arduino setup function):

dht.begin();

Then read the humidity and temperature using these functions:

float h = dht.readHumidity();

float t = dht.readTemperature();    // Read temperature as Celsius

float f = dht.readTemperature(true);    // Read temperature as Fahrenheit

DHT Library Notes

Sensor Update

The sensor is slow to change its output value (update) which is 2s for DHT22. The library code will return the previous value if you ask for the data too often (see code snippet below) - if you use a different library check that this is the case. 

Interestingly the DHT11 allows a faster update rate (1s) compared to the DHT22 (2s) but this enables the DHT22 to offer a better relative humidity measurement (2%RH) as opposed to (5%RH) for the DHT11.

Code : in DHT.cpp for public function read(void)

boolean DHT::read(void) {
  uint8_t laststate = HIGH;
  uint8_t counter = 0;
  uint8_t j = 0, i;
  unsigned long currenttime;

  // Check if sensor was read less than two seconds ago and return early
  // to use last reading.
  currenttime = millis();
  if (currenttime < _lastreadtime) {
    // ie there was a rollover
    _lastreadtime = 0;
  }

  if (!firstreading && ((currenttime - _lastreadtime) < 2000)) {
    return true; // return last correct measurement
    //delay(2000 - (currenttime - _lastreadtime));
  }

  firstreading = false;

/*
Serial.print("Currtime: ");  Serial.print(currenttime);
Serial.print(" Lasttime: "); Serial.print(_lastreadtime);
*/
  _lastreadtime = millis();

Output

• Relative Humidity,
• Temperature,
• Heat Index,
• Dew Point.

Warnings

Application Ideas:

Shower room : When the air gets too saturated start an extractor fan to get rid of wet air.

Weather Station : Relative Humidity,Temperature and Dew point data logger.

Tumble Dryer : Automatic shut down at a specific humidity level (does not have to be bone dry e.g. for ironing clothes, you need a higher humidity level).

Environmental control : Preservation of books/materials ensuring that the air is not saturated i.e. measuring the dew point - and automatic action when the temperature gets close to the dew point - e.g. extractor fans and/or controlling temperature.

Humidity Control System : Control the amount of water in the air using a microcontroller and water vaporiser e.g. an ultrasonic vaporiser.

Search:

Recent Articles

• 
• 

1. Arduino Hall Effect Sensor Tutorial: Detect Magnets Easily

   
   Arduino Hall Effect Sensor: Add magnetic sensing superpowers to your Arduino projects with an easy-to-use hall effect sensor. With full code and layout...

   Read more

2. Logic Level Converter: Easily Convert between 5V and 3V

   
   Logic Level Converter: How to create a bi-directional interface that automatically translates voltage levels using a subtle MOSFET property...

   Read more

3. Arduino Ultrasonic Sensors: A Beginner's Guide to the HC SR04

   
   A step-by-step guide to using Arduino ultrasonic sensors for object detection and distance measurement. Details the libraries you need, example code and circuit diagram.

   Read more

4. Arduino Humidity Sensor: A Beginners Tutorial on the DHT11 sensor

   
   Get started with an Arduino humidity sensor using the DHT11, which reports both humidity and temperature. Complete guide with full code for using this sensor

   Read more

5. A beginners Arduino Project to Control an LED with a Button

   
   This beginners guide shows you how to build a simple Arduino circuit to control an LED using a push button. Full connection details and example program included...

   Read more

6. Arduino digitalRead; A tutorial on Reliably reading Push Buttons

   
   In this beginner Arduino digitalRead tutorial you'll learn how to use the digitalRead function to read a button avoiding switch bounce. Full example code and explanation included

   Read more